Skip to content

Instantly share code, notes, and snippets.

@SteveALee

SteveALee/README.md

Last active November 11, 2025 15:24
Show Gist options

  • Select an option

    Learn more about clone URLs
  • Save SteveALee/da24c2be633340b8791066dd98eb5d0b to your computer and use it in GitHub Desktop.

Select an option

Learn more about clone URLs
Save SteveALee/da24c2be633340b8791066dd98eb5d0b to your computer and use it in GitHub Desktop.
Download ZIP
Build audacity with ASIO support on Windows
Raw
README.md

Build your own Audacity for Windows with ASIO driver support

!!Breaking news - Steinberg recently open sourced the ASIO SDK (GPLv3) so Audacity will be able to release ASIO binaries. As they are focussed on Audacity 4 it might not happen anytime soon though!!

You might want Audacity to work with the ASIO drivers supplied with your sound devices. Commmon reasons for this are:

  • Only ASIO drivers are available for your hardware (eg Behringer mixers)
  • Performance - ASIO has low latency (delays)
  • You don't want to use the ASIO4All bridging driver with non ASIO drivers
  • Multi channel support - though Audacity is not so good at handling other than Stereo or Mono

Due to licensing restrictions the Audacity team cannot provide a prebuilt version with Windows ASIO driver support. But with this guide and script you can easily build your own Audacity with ASIO support, on a Windows PC.

This builds the latest Audacity release 3.7.5 by default. Recent other versions can be built with the -v option

ko-fi

Background

Drivers are the glue between an audio program like Audacity and external hardware like a mixer or sound interface. The drivers usually used on Windows have limitations which can be overcome if you use ASIO drivers for your hardware. Specifically, low latency (delay) and multi channel support are available with ASIO drivers.

The Audacity program is the "go to" solution for many audio recording and editing tasks. However, unlike many more advanced DAWs, it doesn't support Windows ASIO drivers "out of the box". Fortunately, Audiacity's standard MME support is fine for most uses. That said, common reasons for needing ASIO include using digital audio or music equipment that only comes with ASIO drivers, such as Behringer mixers (which actually suggest using the less efficient ASIO4ALL ASIO to WDM bridging driver). Another common reason is to take advantage of the low latency or multiple channels supported by ASIO. Note that Audacity really is not a good multichannel solution, so if that is required a DAW might be a better bet.

While it is possible to build your own Audacity with ASIO support by following the instructions this usually requires considerable technical skills.

But have no fear, the instructions and script provided here make it easy to build your own version of Audacity with ASIO support. You just need a suitable Windows PC. The script installs all required tools and builds a 64 bit release version of Audacity with ASIO for you using the official build instructions.

NB. If you do use this to build Audacity with ASIO support you must not redistribute it due to the ASIO SDK licensing terms - see below.

Here's a brief blog post explaining why I needed ASIO and it includes a screen shot. But note, since writing that, I discovered my McMillen K-Mix digital interface mixer facilities alow routing of inputs 3 & 4 to the main outputs on 1 and 2 so can use the default MME Audacity build after all. For playback from PC, I found the HiFi Driver and ASIO Bridge from VB Audio lets me re-route PC audio out to channels 3 & 4 on the K-Mix, Leaving Channels 1 & 2 free for instruments and Mics.

Licensing

The reason for Audacity's lack of ASIO support is licensing, not technical. Steinberg do not alow the ASIO SDK to be redistributed (as required by open source projects). In addition, Audacity is GPL licensed and so is incompatible with the ASIO SDK licence redistribution rules.

Development PC

The script installs a set of development tools that are known to build Audacity. Due to the complex nature of such tools, any other versions of them on your PC may interfere with this script. Thus this scipt should be run on a clean PC without any developer tools. No support can be offered otherwise.

If you would rather not install these tools (Git for Windows, Visual Studio, CMake, Python and Conan), or you already have versions of them or even if you are having build problems, you can use a one of the following Vitual Machines:

  • Windows Sandbox - Sandbox can be enabled on Windows 10/11 Pro/Enterprise and can also be installed on Windows Home with a bit of effort. If the build experiences memory errors you will need a configuration file to provide more memory than the default 4GB.
  • A virtualisation program - install a VM and and a matching Developer Virtual Machine Image from Microsoft. In most cases VirtualBox will be a good choice (import the Microsoft supplied .ova appliance file but the Visual Studio pre installed in the VM must be uninstalled first to avoid problems).

In both cases you can copy the built files to where they will be run from on you PC file system, possibly by sharing a PC folder with the VM.

Step by Step Instructions

  • Ensure you have a PC (or VM) with Windows 10 or 11 installed.
  • Make a new folder C:\projects.
  • Click on the 'raw' button at the top of the script (below) in this Gist.
  • Use the browser Save As (right click) feature to save the script as This PC -> C:\projects\build-audacity.cmd. To avoid it being saved as a text file type the filename in quotes, eg "build-audacity.cmd".
  • open a new Windows cmd terminal (Windows + R keys and then type cmd)
  • Type cd \projects and enter key.
  • Install required tools and build by typing build-audacity.cmd and enter (use -v3.3.3 if requred).
    • Follow the prompts, pressing a key to start each tool's installer (when previous has finished).
    • NB for Visual Studio, make sure you check the "desktop development with C++" workload
    • If you have a non English Windows or Visual Studio then you must also install the English language packs.
  • Come back later - it will take at least 10 minutes.
  • Audactiy will be launched to test it was built correctly.
    • See the program location printed out at the end of the build so you can run it again.
    • Optionally copy the specified folder to where you want to run Audacity from, optionally renaming it.

(This video by @Renamesk walks you through the process, but the tool installation method has changed.)

If you have any ASIO drivers installed for active connected hardware you should find ASIO is now available in the the Audacity driver selection combo box which probably currently shows 'MME' selected (you may need to show using menu item View -> Toolbars -> Device toolbar).

NB: The Audacity settings and preferences are stored in a folder "Portable Settings" next to the audacity program. If you want to use settings in the user's home directory then delete this folder.

ko-fi

When things go wrong

As with any complex software build there are many moving parts (including Windows itself) and things can sometimes go wrong. Here are some tips if you hit build errors.

If everyhting falls or you just want to shortcut lots of painful debugging then try a Microsoft Windows Virtual machine (VM) as mentioned above.

  • make sure you have latest script
  • make sure you are in a folder C:\projects in the cmd window
  • ensure you are an administrator on your Windows 10 or 11 64 bit PC (ie not a organisational PC)?
  • run the script with --cleanall and try again
  • uninstall all the tools and installers (Python, cmake, Visual Studio) and then reboot before trying again
    • note having other versions of any of the tools installed may well cause problems - remove them
  • ensure you ticked the specified options when installing Visual Studio and Python, reinstall if unsure
  • read the error output - clues are often buried in reams of impenetrable text
  • disable any Anti Virus - the built-in Microsoft one is usually not a problem
  • if your PC is not English make sure you have EN language packs installed for Windows and VS

Thanks

  • @diogodh for finding and fixing the bug with conan installations
  • The Audacity team for an fantastic audio tool

ko-fi

Raw
build-audacity.cmd
@echo off
rem Version: 2.15.0
rem
rem See the following gist for details
rem https://gist.github.com/SteveALee/da24c2be633340b8791066dd98eb5d0b
rem
rem Options (only one may be specified)
rem
rem --install or none - install tools and build
rem --build - build, no install
rem --noget - build only but don't fetch again from git
rem --getonly - only get the files
rem --rebuild - cleanall and build
rem --clean - remove built files
rem --cleanall - remove fetched, built files and conan modules
rem --cleaninstall - remove downloaded installation files
rem -vj.m.p version - default is 3.7.5 (using conan 2.3.2) - limited due to dependencies
rem
rem MIT licence
rem [email protected]
TITLE Build Audacity with ASIO
setlocal
rem Clean up arguments
set TARGET=%1
set VERSION=%2
rem substring on empty var fails within parenthesis
if not [%TARGET%] == [] set TARGET_PREFIX=%TARGET:~0,2%
if [%TARGET_PREFIX%] == [-v] (
set TARGET=%2
set VERSION=%1
)
if [%TARGET%] == [] set TARGET=--install
if [%VERSION%] == [] (
set AUDACITY_REL=3.7.5
) else (
set AUDACITY_REL=%VERSION:~2%
)
set VISUALSTUDIOVER=2022\Community
set VISUALSTUDIOCMAKE=Visual Studio 17 2022
set VSDIR=%ProgramFiles%\Microsoft Visual Studio\%VISUALSTUDIOVER%
set PROJROOT=C:\projects
set AUDACITY=%PROJROOT%\audacity
set AUDACITY_BUILD=%PROJROOT%\audacity-asio
set MAKE_CONFIG=RelWithDebInfo
set EXEDIR=%AUDACITY_BUILD%\%MAKE_CONFIG%
set INSTALLFILEDIR=bin
rem More vaiables set for --install
if [%AUDACITY_REL:~0,3%] == [3.3] (set CONAN_VER=1.59.0) else (set CONAN_VER=2.11.0)
set CMAKE_OPTS=-DAUDACITY_BUILD_LEVEL=2 -Daudacity_has_asio_support=On
if [%AUDACITY_REL:~0,3%] GEQ [3.5] set CMAKE_OPTS=%CMAKE_OPTS% -Daudacity_has_audiocom_upload=On -Daudacity_has_networking=On -Daudacity_has_url_schemes_support=On
rem check projroot exists
if /I not [%~dp0] == [%PROJROOT%\] (
echo.
echo Error: This script must be run in %PROJROOT% - see %%PROJROOT%% in file
echo.
if not exist %PROJROOT% (
echo Create %PROJROOT
goto exit
) else (
echo cd to %PROJROOT%
goto exit
)
)
echo.
echo Building Audacity %AUDACITY_REL% 64 bit RelWithDebInfo with ASIO support...
echo.
rem Get tools
rem ANSI escape sequences do not work in if () block so we use goto
set git-url=https://github.com/git-for-windows/git/releases/download/v2.51.0.windows.1/Git-2.51.0-64-bit.exe
set GITPATH=%ProgramFiles%\Git\cmd\
set vs2022-url=https://aka.ms/vs/17/release/vs_community.exe
rem Conan is installed later
if [%CONAN_VER:~0,1%] == [1] (
rem Note Conan 1.59 has dependency issues with python 3.12
set python-url=https://www.python.org/ftp/python/3.11.0/python-3.11.0-amd64.exe
set PYTHONPATH=%LOCALAPPDATA%\Programs\Python\Python311\
) else (
set python-url=https://www.python.org/ftp/python/3.13.7/python-3.13.7-amd64.exe
set PYTHONPATH=%LOCALAPPDATA%\Programs\Python\Python313\
)
set PIPPATH=%PYTHONPATH%Scripts\
if not [%TARGET%] == [--install] if not [%TARGET%] == [--cleaninstall] goto clean
if [%TARGET%] == [--cleaninstall] echo Cleaning installation files... & rmdir /s/q %INSTALLFILEDIR% 2> :null & goto exit
echo   
echo.
echo Fetching tools..
echo 
mkdir %INSTALLFILEDIR% 2> :null
curl -L %git-url% -o %INSTALLFILEDIR%\g4w.exe
curl -L %vs2022-url% -o %INSTALLFILEDIR%\vs.exe
curl -L %python-url% -o %INSTALLFILEDIR%\python.exe
echo   
echo.
echo Installing tools...
echo.
echo IMPORTANT!! Follow the instructions below for each installer
echo Close each installer when it is done before starting next
echo.
echo Git for Windows
echo Choose the option "Git from the command line..."
pause
%INSTALLFILEDIR%\g4w.exe
echo.
echo Visual Studio: make sure you select the Workload "Desktop development with C++"
echo You can uncheck "Start After installation"
pause
%INSTALLFILEDIR%\vs.exe
echo.
echo Python: make sure you select "Add python.exe to PATH" for future access
pause
%INSTALLFILEDIR%\python.exe
echo.
echo.
echo 
set installing=true
call :clean --rebuild
goto exit
:clean
rem Python is on path, unless in windows sandbox
rem where /q python & if ERRORLEVEL 1 path %PATH%;%PYTHONPATH%
rem where /q pip & if ERRORLEVEL 1 path %PATH%;%PIPPATH%
rem where /q git & if ERRORLEVEL 1 path %PATH%;%GITPATH%
path %PYTHONPATH%;%PIPPATH%;%GITPATH%;%PATH%
if not [%TARGET%] == [--getonly] (
if /I [%TARGET%] == [--clean] echo Cleaning built files... & rmdir /s/q %AUDACITY_BUILD% 2> :null & goto exit
if /I [%TARGET%] == [--cleanall] call :cleanall & goto exit
if /I [%TARGET%] == [--rebuild] call :cleanall
)
goto skip
rem subroutine
:cleanall
echo Cleaning source and built files... & rmdir /s/q %AUDACITY% %AUDACITY_BUILD% 2> :null
where /q conan & if ERRORLEVEL 0 echo Cleaning conan cache... & conan remove -c "*" 2>&1 > :null
exit /B
:skip
rem Launch cmake-gui
rem VS doesn't include this with it's cmake
rem if [%TARGET%]==[--gui] cmake-gui -Daudacity_has_asio_support=On %CMAKE_OPTS% -S %AUDACITY% -B %AUDACITY_BUILD% & goto build
:checktools
rem ensure tools are installed
if not [%TARGET%] == [--noget] (
where /q git & if ERRORLEVEL 1 echo Git for Windows does not appear to be installed. Rerun with "--install" & goto exit /b
)
if not [%TARGET%] == [--getonly] (
if not exist "%VSDIR%\VC\Auxiliary\Build\vcvars64.bat" echo Visual Studio does not appear to be installed. Re run with "--install" & goto exit /b
if not defined VisualStudioVersion call "%VSDIR%\VC\Auxiliary\Build\vcvars64.bat"
where /q python & if ERRORLEVEL 1 echo Python does not appear to be installed. Open a new cmd window or re-run with "--install" & goto exit /b
where /q conan & if ERRORLEVEL 0 pip show --version conan | findstr /R /C:"Version: %CONAN_VER%" & if ERRORLEVEL 1 echo conan %CONAN_VER% not found & pip uninstall -y -q conan
where /q conan & if ERRORLEVEL 1 echo installing conan %CONAN_VER% & pip install conan==%CONAN_VER%
)
rem Get source code
:getcode
if /I not [%TARGET%] == [--clean] (
if /I not [%TARGET%] == [--cleanall] (
if /I not [%TARGET%] == [--noget] (
echo Fetching code for Audacity %AUDACITY_REL%...
echo.
git clone -b Audacity-%AUDACITY_REL% --depth 1 https://github.com/audacity/audacity/ %AUDACITY%
if ERRORLEVEL 1 echo Error: cannot fetch the Audacity code. Try the --cleanall or --noget options & goto exit
)
)
)
if /I [%TARGET%] == [--getonly] goto exit
if not exist %AUDACITY%\CMakeLists.txt echo The code files appear to be missing from %AUDACITY%. & goto exit
:cmake
cd %AUDACITY%
cmake.exe -G "%VISUALSTUDIOCMAKE%" -DCMAKE_CONFIGURATION_TYPES=%MAKE_CONFIG% %CMAKE_OPTS% -S %AUDACITY% -B %AUDACITY_BUILD% & if ERRORLEVEL 1 echo Error: Cannot create Audacity buildfiles & goto exit
:build
cd %AUDACITY_BUILD%
set msbuild="%VSDIR%\MSBuild\Current\Bin\MsBuild.exe"
%msbuild% ALL_BUILD.vcxproj -p:configuration=%MAKE_CONFIG%
if ERRORLEVEL 1 echo Error: cannot build Audacity & goto exit
rem Settings stored with files rather than home directory
rem See https://manual.audacityteam.org/man/portable_audacity.html
mkdir %EXEDIR%\"Portable Settings"
cd %PROJROOT%
rem All done
echo 
echo.
echo Congratulations!
echo Your new Audacity %AUDACITY_REL% with ASIO support will now launch.
echo The ASIO options will appear if you have ASIO drivers and connected hardware
echo In future just run the audacity.exe. No need to install.
echo.
echo %EXEDIR%\audacity.exe
echo.
echo Or copy the folder
echo.
echo %EXEDIR%\
echo.
echo and run the included audacity.exe
echo.
echo Note settings and preferences are stored in "%EXEDIR%\Portable Settings"
echo If you want to use settings in the user's home directory then delete this folder.
echo.
echo 
start %EXEDIR%\audacity.exe
if defined installing exit /B
:exit
cd %PROJROOT%
endlocal
@SteveALee
Copy link
Author

SteveALee commented Oct 2, 2025

@The-Real-Rustla ah, the build process changed over time and supporting old version builds would be very much work. The script does try to handle some conan version differences but seems it breaks here. :(

I do understand your frustrations with recent audacity versions so I will try to take a look soon.

@SteveALee
Copy link
Author

SteveALee commented Oct 2, 2025 •
edited
Loading

@The-Real-Rustla The build process has change too much since 3.1.x for the script to support it. All I can suggest is you try building it yourself followingt the projetc build instructions https://github.com/audacity/audacity/blob/Audacity-3.1.3/BUILDING.md

@The-Real-Rustla
Copy link

The-Real-Rustla commented Oct 2, 2025 via email

@SteveALee
Copy link
Author

SteveALee commented Oct 2, 2025

Good, but just too old a version for the script. Please see comment above.

@The-Real-Rustla
Copy link

The-Real-Rustla commented Oct 2, 2025

Good, but just too old a version for the script. Please see comment above.

Sorry, replied by email to the unedited response.

I did build 3.0.2 manually years ago, so I will give 3.1.3 a go manually too.

Thanks for your work on this script anyway, going forward I'm sure I will use it, especially when/if you update it for the 4.x.x version when it gets released, as they promised that this will have the reset of the metering peaks issue sorted in that. (only took 5 sub versions or a few years). Or will it work with the pre release V4?

@SteveALee
Copy link
Author

SteveALee commented Oct 2, 2025

especially when/if you update it for the 4.x.x version

@The-Real-Rustla i was just thinking about that. I guess it depends on what i think of 4 and how complex build is. I spend less time coding these days.

Thanks for your feedback. 😀

@SteveALee
Copy link
Author

SteveALee commented Oct 3, 2025 •
edited
Loading

@The-Real-Rustla you might be in luck as I recalled gists are actually git repos and I dug out the script version for 3.1.2. I tried it but it falls over with a conan error. That might just be coz I don't have a really clean dev env. DM me and I'll send you the script to try if you like.

@Giermann
Copy link

Giermann commented Oct 8, 2025

He can also just search for it himself by clicking on "Revisions" on top and scroll through the changes.
Last version for 3.1.2 was this:
https://gist.github.com/SteveALee/da24c2be633340b8791066dd98eb5d0b/1e49fd6e21fa9ae98dbb3c04e6a8850b401c1c4c

@SteveALee
Copy link
Author

SteveALee commented Oct 8, 2025

@Giermann i missed that UI completely and cloned locally to search. Thanks.

@LeoWattenberg
Copy link

LeoWattenberg commented Nov 4, 2025

ASIO got open sourced recently, so it's now possible to distribute binaries of it. The Audacity team will no doubt do that for the upcoming 4.0 and maybe the last 3.7.x release; in the meantime, I made a precompiled binary here: https://github.com/LeoWattenberg/audacity/releases/tag/asio

@SteveALee
Copy link
Author

SteveALee commented Nov 4, 2025

@LeoWattenberg said:

ASIO got open sourced recently,

Wow - really!? Not heard that. What took them so long!!! LOL. I wonder if Steinberg was influenced by Microsoft's goal of shipping it in Windows.

Thanks for the link but as always I would caution everyone to be careful with installing unverified binaries!

@SteveALee
Copy link
Author

SteveALee commented Nov 4, 2025

More info from Steinberg. The ASIO SDK is dual licensed under GPL 3 so will be compatible with Audacity. VST also open sourced under MIT, but there's an "iffy" statement on logo use. Good News

@Chris-C-Bristol
Copy link

Chris-C-Bristol commented Nov 4, 2025 via email •
edited by SteveALee
Loading

@SteveALee
Copy link
Author

SteveALee commented Nov 4, 2025

@Chris-C-Bristol No idea! LOL
If that's the options in Audacity when you run it then you probably wan't the one that came with the Behringer. Maybe Generic one?
Prepare to be underwhelmed with the multi-channel support of Audacity!

@Chris-C-Bristol
Copy link

Chris-C-Bristol commented Nov 4, 2025 via email •
edited by SteveALee
Loading

@Chris-C-Bristol
Copy link

Chris-C-Bristol commented Nov 5, 2025 via email •
edited by SteveALee
Loading

@SteveALee
Copy link
Author

SteveALee commented Nov 5, 2025

Good grief! So much for simplicity. Best of luck.

@SteveALee
Copy link
Author

SteveALee commented Nov 5, 2025

I heard microsoft planned to provide ASIO in Windows, perhaps along with MIDI 2 support. But i dont know what or how you'd use it.

@Giermann
Copy link

Giermann commented Nov 6, 2025

@Chris-C-Bristol
This "Steinberg built-in ASIO Driver" should be compatible with Windows 10 too, but I never tested it.
According to the help article, there should be a control panel - maybe you can find some information, why it only offers 1 channel:
https://helpcenter.steinberg.de/hc/en-us/articles/17863730844946-Steinberg-built-in-ASIO-Driver-information-download

@Chris-C-Bristol
Copy link

Chris-C-Bristol commented Nov 11, 2025 via email •
edited by SteveALee
Loading

@SteveALee
Copy link
Author

SteveALee commented Nov 11, 2025

@Chris-C-Bristol good grief! Thanks for the info.

Sign up for free to join this conversation on GitHub. Already have an account? Sign in to comment