nadako · April 21, 2016 02:35 · Apr 21, 2016
diff --git a/FunctionArgMacro.hx b/FunctionArgMacro.hx
@@ -0,0 +1,33 @@
+import haxe.macro.Context;
+import haxe.macro.Expr;
+
+class FunctionArgMacro {
+    macro static function build():Array<Field> {
+        var fields = Context.getBuildFields();
+        for (field in fields) {
+            switch (field.kind) {
+                case FFun(fun):
+                    var checks = [];
+                    for (arg in fun.args) {
+                        switch (arg.type) {
+                            case macro : String:
+                                for (m in arg.meta) {
+                                    switch (m.name) {
+                                        case "notNullOrEmpty":
+                                            checks.push(macro if ($i{arg.name} == null) throw $v{arg.name + " is null"});
+                                            checks.push(macro if ($i{arg.name}.length == 0) throw $v{arg.name + " is empty"});
+                                    }
+                                }
+                            default:
+                        }
+                    }
+                    fun.expr = macro {
+                        $b{checks};
+                        ${fun.expr};
+                    }
+                default:
+            }
+        }
+        return fields;
+    }
+}
diff --git a/Main.hx b/Main.hx
@@ -0,0 +1,9 @@
+@:build(FunctionArgMacro.build())
+class Main {
+    static function main() {
+    }
+
+    static function greet(@notNullOrEmpty who:String) {
+        trace('Hi, $who!');
+    }
+}
diff --git a/main.js b/main.js
@@ -0,0 +1,9 @@
+Main.greet = function(who) {
+	if(who == null) {
+		throw new js__$Boot_HaxeError("who is null");
+	}
+	if(who.length == 0) {
+		throw new js__$Boot_HaxeError("who is empty");
+	}
+	console.log("Hi, " + who + "!");
+};
No results found